关于sqlserver always on群集创建登录名和数据库用户名丢失关联

最近部署遇到一个问题，在always on 群集主节点用ssms工具创建登录名，然后故障故障转移到从节点创建登录名，用
sp_change_users_login 关联后，先前主节点登录名和数据库用户名就会丢失关联，这样集群就会有问题

经调查，sqlserver 的登录名和用户名是用sid关联的，调查如下
1.主节点1创建一个登录名，如图，查询登录名和用户的sid是相同的
在这里插入图片描述
2.然后故障转移到节点2，在节点2创建登录名，即使创建登录名称和数据库用户一致，但是sid却不一致，所以二者并不关联
exec sp_change_users_login ‘UPDATE_ONE’,‘用户名’,‘登录名’ 使得节点2登录名和数据库用户名一致，此时数据库用户名的sid 改成节点2的登录名的sid，节点1数据库用户名sid被覆盖二者关联上
在这里插入图片描述
3这时查看节点1的信息，登录名sid 和数据库用户名sid 丢失关联，这就导致每次故障转移，就会丢失二者关联，导致sqlserver无法登录

解决：
1.在主节点执行以下sqlserver 存储过程

/*
--SQL 数据库导出迁移用户账户及权限
--EG. [sp_help_revlogin]
*/

--sp_hexadecimal
   USE master
GO
IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
  DROP PROCEDURE sp_hexadecimal
GO
CREATE PROCEDURE sp_hexadecimal
    @binvalue varbinary(256),
    @hexvalue varchar(256) OUTPUT
AS
DECLARE @charvalue varchar(256)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
  DECLARE @tempint int
  DECLARE @firstint int
  DECLARE @secondint int
  SELECT @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
  SELECT @firstint = FLOOR(@tempint/16)
  SELECT @secondint = @tempint - (@firstint*16)
  SELECT @charvalue = @charvalue +
    SUBSTRING(@hexstring, @firstint+1, 1) +
    SUBSTRING(@hexstring, @secondint+1, 1)
  SELECT @i = @i + 1
END
SELECT @hexvalue = @charvalue
GO

----- sp_help_revlogin

IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
  DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE [dbo].[sp_help_revlogin] @login_name sysname = NULL AS  
    DECLARE @name sysname  
    DECLARE @type varchar (1)  
    DECLARE @hasaccess int  
    DECLARE @denylogin int  
    DECLARE @is_disabled int  
    DECLARE @PWD_varbinary  varbinary (256)  
    DECLARE @PWD_string  varchar (514)  
    DECLARE @SID_varbinary varbinary (85)  
    DECLARE @SID_string varchar (514)  
    DECLARE @tmpstr  varchar (1024)  
    DECLARE @is_policy_checked varchar (3)  
    DECLARE @is_expiration_checked varchar (3)  
    DECLARE @defaultdb sysname  
    IF (@login_name IS NULL)  
    DECLARE login_curs CURSOR FOR  
    SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM  
    sys.server_principals p LEFT JOIN sys.syslogins l  
    ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name <> 'sa'  
    ELSE  
    DECLARE login_curs CURSOR FOR  
    SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM  
    sys.server_principals p LEFT JOIN sys.syslogins l  
    ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name = @login_name  
    OPEN login_curs  
    FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin  
    IF (@@fetch_status = -1)  
    BEGIN  
    PRINT 'No login(s) found.'  
    CLOSE login_curs  
    DEALLOCATE login_curs  
    RETURN -1  
    END  
    SET @tmpstr = '/* sp_help_revlogin script '
    PRINT @tmpstr  
    SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'  
    PRINT @tmpstr  
    PRINT ''  
    WHILE (@@fetch_status <> -1)  
    BEGIN  
    IF (@@fetch_status <> -2)  
    BEGIN  
    PRINT ''  
    SET @tmpstr = '-- Login: ' + @name  
    PRINT @tmpstr  
    IF (@type IN ( 'G', 'U'))  
    BEGIN -- NT authenticated account/group  
    SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']'  
    END  
    ELSE BEGIN -- SQL Server authentication
    SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) )  
    EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT  
    EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT
   SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN
0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name  

    SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN
0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name  

    SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED,
    SID = ' + @SID_string + ', DEFAULT_DATABASE = [' + @defaultdb + ']'  

    IF ( @is_policy_checked IS NOT NULL )  
    BEGIN  
    SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked  
    END  
    IF ( @is_expiration_checked IS NOT NULL )  
    BEGIN  
    SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked  
    END  
    END  
    IF (@denylogin = 1)  
    BEGIN -- login is denied access  
    SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name )  
    END  
    ELSE IF (@hasaccess = 0)  
    BEGIN -- login exists but does not have access  
    SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name )  
    END  
    IF (@is_disabled = 1)  
    BEGIN -- login is disabled  
    SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE'  
    END  
    PRINT @tmpstr  
    END  
    FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin  
    END  
    CLOSE login_curs  
    DEALLOCATE login_curs  
    RETURN 0

2.在主节点执行存储过程，选择自己创建的用户
exec sp_help_revlogin
在这里插入图片描述